Effects spéciaux avec Thymio II

Les films qu'on voit au cinéma sont désormais remplis d'effets spéciaux plus ou moins sophistiqués. Si la pluspart de ces effets impliquent des techniques compliquées, il y a des effets simples qui peuvent donner des résultats intéressants. Un effet spécial parmi les plus simples est de jouer la vidéo à l'envers. Cet exemple d'utilisation de Thymio II joue sur cet effet.

Le petit clip ci dessous joue sur le contraste entre le Thymio II qui semble évoluer normalement, et le reste du monde qui fonctionne à l'envers.

L'idée de cette vidéo vient de l'excellent clip "forward":

D'autres vidéos robotiques ont été faites selon le même principe, comme par exemple la suivante:

Comment faire?

L'effet est obtenu en filmant le robot qui recule, tout en laissant le reste du monde autour de lui évoluer normalement. On part donc de la situation finale pour reculer jusqu'à la situation initiale.

Voici ce que donne cette vidéo à l'"endroit" (notez que les sons sont justes à l'exceptions de quelques effets sonores ajoutés au clip après inversion):

Pour faire cela de façon crédible et pouvoir télécommander correctement le robot, un programme spécial a été développé pour pouvoir télécommander le robot tout en ayant un mode "jaune" comme l'explorateur. On a donc l'impression d'avoir le robot qui avance normalement mais en effet on peut le télécommander en marche arrière. Voici le code pour réaliser cela:

var temp
var rc5_speed_l
var rc5_speed_t
var vmin=-600
var vmax=600

var led_pulse

timer.period[0]=20

sub setmotor
    call math.min(rc5_speed_t, rc5_speed_t, vmax)
    call math.max(rc5_speed_t, rc5_speed_t, vmin)
    call math.min(rc5_speed_l, rc5_speed_l, vmax)
    call math.max(rc5_speed_l, rc5_speed_l, vmin)    
    motor.left.target  = rc5_speed_l + rc5_speed_t
    motor.right.target  = rc5_speed_l - rc5_speed_t

onevent timer0
    #Body color pulse
    led_pulse = led_pulse + 1
    if led_pulse > 0 then
        call leds.top(led_pulse,led_pulse,0)
        if led_pulse > 40 then
            led_pulse = -64
        end
    else 
    temp=-led_pulse/2
    call leds.top(temp, temp, 0)
    end

onevent rc5
    if rc5.command !=0 then
        if rc5.command == 32 then
                if rc5_speed_t!=0 then
                    rc5_speed_t = 0
                else
                    rc5_speed_l = rc5_speed_l+50
                end                    
        elseif rc5.command == 17 then
                rc5_speed_t = -50            
        elseif rc5.command == 33 then
                if rc5_speed_t!=0 then
                    rc5_speed_t = 0
                else
                    rc5_speed_l = rc5_speed_l-50
                end
        elseif rc5.command == 16 then
                rc5_speed_t = 50
        elseif rc5.command == 13 then
                rc5_speed_t = 0
                rc5_speed_l = 0
        end
        rc5.command = 0
        callsub setmotor

    end

Une fois ce film réalisé on le joue à l'envers. Ceci est une simple option du clip dans les logiciels d'édition vidéo comme iMovie. Pour le bruitage on peut ajouter des effets ou laisser le son original inversé, ce qui donne assez bien comme, dans ce clip.

Pour arriver à la version finale il faut faire plusieures versions et comprendre quelles actions donnent bien à l'envers. Bonne expérimentation à tous et n'hésitez pas à ajouter sur cette page votre vidéo!

Unless otherwise stated, the content of this page is licensed under Creative Commons Attribution-ShareAlike 3.0 License