Loop or logic blocks in Events

1. Home
2. Creations
3. Forum
4. Contributions
5. Documentation

Forum

Summary:

Is it possible to put a Loop or a logic block in an Event?

Loop or logic blocks in Events

Marvin H 10 Aug 2017 12:21

I want to programm the Thymio, so he can find his way thru a Labyrinth (there are no dead ends in the labyrinth). But i'm trying to increase the Programm by kind of telling Thymio, from which way he came from.

So if there is a wall in front of him, he turns 90-degree to the right. If there is still a wall in front of him, he's turning 180-degree to left (or right) and move forward. If there is no wall after a his first 90-degree turn, then he moves forwards.

So there is no chance of going in the direction he came from.

My code from the Blockly looks like this:

onevent button.forward
when button.forward == 1 do
call leds.top(6,32,6)
motor.left.target = 100
motor.right.target = 100
end

onevent prox
when prox.horizontal[2] > 2000 do
call leds.top(32,0,0)
timer.period[0] = 800
motor.left.target = 300
motor.right.target = -300
end

onevent timer0
call leds.top(26,6,26)
if (prox.horizontal[2] > 2000 or prox.horizontal[3] > 2000) or prox.horizontal[1] > 2000 then
timer.period[1] = 1300
motor.left.target = -300
motor.right.target = 300
else
motor.left.target = 100
motor.right.target = 100
end

onevent timer1
call leds.top(32,19,0)
motor.left.target = 100
motor.right.target = 100

Can anyone help me please?

Re: Loop or logic blocks in Events

riedo 31 Aug 2017 13:26

Hi!

I think your main problem is with the usage of the timers. Once a timer is set, for example at a period of 800 ms, the timer event will keep happening every 800 ms. thus once the 2 timers are set in your program, it becomes very confusing.

I suggest you think in terms of what we call a state machine. This means that you should think about the behaviour your robot could have, and the conditions for your robot to switch from one behaviour to the other.

Just to give you an idea, here is what I came up with:
(I had programmed in blockly at first but because blockly uses when for the conditions on proximity sensors it did not work as I had intended, so I switched to text mode and replaced when with if)

var compteur[1]
var state[1]
var checking[1]

timer.period[0] = 1
state[0] = 0
checking[0] = 1
compteur[0] = 0
motor.left.target = 100
motor.right.target = 100

onevent prox
    if prox.horizontal[2] > 2000 then
        if checking[0] == 1 and state[0] == 0 then
            motor.left.target = -300
            motor.right.target = 300
            compteur[0] = 800
            state[0] = 1
            checking[0] = 0
        elseif checking[0] == 1 and state[0] == 1 then
            motor.left.target = 300
            motor.right.target = -300
            compteur[0] = 1300
            state[0] = 2
            checking[0] = 0
        end
    end

    if prox.horizontal[2] < 1000 then
        if checking[0] == 1 then
            motor.left.target = 100
            motor.right.target = 100
            compteur[0] = 0
            state[0] = 0
            checking[0] = 1
        end
    end

onevent timer0
    if compteur[0] > 0 then
        compteur[0] = compteur[0] - 1
    elseif compteur[0] == 0 then
        checking[0] = 1
    end

As you can see I used variables to remember what I am doing. basically I setup a timer that runs continuously, then if I need to measure a certain amount of time I use a counter variable that is decremented. Then the state variable says if I'm going forward, turning left or turning right. Finally the checking variable informs me if I should check the sensors or not (while I'm turning 90°, I don't want the change on the sensors to affect me until I'm done turning. I could also use the counter value to check that, as when counter >0 it means I'm turning)